Key.isToggled()

Доступность

Flash Player 5.

Синтаксис

Key.isToggled(keycode:Number) : Boolean

Параметры

keycode Код клавиши Caps Lock key (20) или Num Lock (144).

Возвращает

Булеву величину.

Описание

Метод: возвращает true, если Caps Lock или Num Lock в данный момент активны; false в противном случае. На Macintosh коды клавиш Caps Lock и Num Lock идентичны.

Пример

В следующем примере методisToggled() вызывается и выводит оповещение на панель Output при каждом включении Caps Lock. В примере создается листнер keyListener, для которого определяется обработчик события onKeyDown, вызывающий Key.isToggled(). Для более подробной информации смотри "Использование листнеров" в Использовании ActionScript во Flash. Объект keyListener затем добавляется в список листнеров объекта Key, транслирующего событие onKeyDown при нажатии клавиши.

var keyListener:Object = new Object();
keyListener.onKeyDown = function() {
  if (Key.isDown(Key.CAPSLOCK)) {
    trace("Вы нажали Caps Lock.");
    trace("\tCaps Lock == "+Key.isToggled(Key.CAPSLOCK));
  }
};
Key.addListener(keyListener);

Информация выводится на панель Output при каждом нажатии клавиши Caps Lock. Панель Output отображает состояние true или false, в зависимости от значения, возвращаемого методом isToggled.

В следующем примере создается два текстовых поля, обновляющихся, когда Caps Lock и Num Lock переключаются.

this.createTextField("capsLock_txt", this.getNextHighestDepth(), 0, 0, 100, 22);
capsLock_txt.autoSize = true;
capsLock_txt.html = true;
this.createTextField("numLock_txt", this.getNextHighestDepth(), 0, 22, 100, 22);
numLock_txt.autoSize = true;
numLock_txt.html = true;
//
var keyListener:Object = new Object();
keyListener.onKeyDown = function() {
  capsLock_txt.htmlText = "<b>Caps Lock:</b> "+Key.isToggled(Key.CAPSLOCK);
  numLock_txt.htmlText = "<b>Num Lock:</b> "+Key.isToggled(144);
};
Key.addListener(keyListener);

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление